FireBeetle 帮你把手机变成键盘鼠标

#define BLINKER_PRINT Serial
#define BLINKER_BLE
#include <Blinker.h>

//键盘数据
char keypress[]  = {0x57, 0xAB, 0x00, 0x02, 0x08, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x10};
//鼠标数据
char mousemove[] = {0x57, 0xAB, 0x00, 0x05, 0x05, 0x01, 0x00, 0x00, 0x00, 0x00, 0x00};

// 左键单击
BlinkerButton Button1("btn-l1");
// 左键双击
BlinkerButton Button2("btn-l2");
// 右键单击
BlinkerButton Button3("btn-r1");
// 中键单击
BlinkerButton Button4("btn-m1");
// 回车
BlinkerButton Button5("btn-rtn");

// 左键单击
void button1_callback(const String & state) {
  BLINKER_LOG("Left Click ", state);
  // 触发鼠标左键
  mousemove[6] = 0x01;
  SendData((byte*)mousemove, sizeof(mousemove));
  delay(10);
  // 鼠标左键抬起
  mousemove[6] = 0x00;
  SendData((byte*)mousemove, sizeof(mousemove));
  delay(10);
}
// 左键双击
void button2_callback(const String & state) {
  BLINKER_LOG("Left Double Click ", state);
  // 触发鼠标左键
  mousemove[6] = 0x01;
  SendData((byte*)mousemove, sizeof(mousemove));
  delay(10);
  // 鼠标左键抬起
  mousemove[6] = 0x00;
  SendData((byte*)mousemove, sizeof(mousemove));
  delay(20);
  // 再来一次
  mousemove[6] = 0x01;
  SendData((byte*)mousemove, sizeof(mousemove));
  delay(10);
  mousemove[6] = 0x00;
  SendData((byte*)mousemove, sizeof(mousemove));
  delay(20);
}
// 右键单击
void button3_callback(const String & state) {
  BLINKER_LOG("Right Click ", state);
  // 触发鼠标右键
  mousemove[6] = 0x02;
  SendData((byte*)mousemove, sizeof(mousemove));
  delay(10);
  mousemove[6] = 0x00;
  SendData((byte*)mousemove, sizeof(mousemove));
  delay(10);
}
// 中键双击
void button4_callback(const String & state) {
  BLINKER_LOG("Middle Click ", state);
  // 触发鼠标中键
  mousemove[6] = 0x04;
  SendData((byte*)mousemove, sizeof(mousemove));
  delay(10);
  mousemove[6] = 0x00;
  SendData((byte*)mousemove, sizeof(mousemove));
  delay(10);
}
// 回车
void button5_callback(const String & state) {
  BLINKER_LOG("Enter ", state);
  // 键盘回车
  keypress[7] = 0x28;
  SendData((byte*)keypress, sizeof(keypress));
  delay(10);
  keypress[7] = 0;
  SendData((byte*)keypress, sizeof(keypress));
  delay(10);
}
// 将 Buffer 指向的内容，size 长度，计算 checksum 之后发送到Serial2
void SendData(byte *Buffer, byte size) {
  byte sum = 0;
  for (int i = 0; i < size - 1; i++) {
    Serial2.write(*Buffer);
    sum = sum + *Buffer;
    Buffer++;
  }
  *Buffer = sum;
  Serial2.write(sum);
}
// 将ASCII 字符转化为 HID Scancode值
byte Asc2Scancode(byte Asc, boolean *shift) {
  if ((Asc >= 'a') && (Asc <= 'z')) {
    *shift = false;
    return (Asc - 'a' + 0x04);
  }
  if ((Asc >= 'A') && (Asc <= 'Z')) {
    *shift = true;
    return (Asc - 'A' + 0x04);
  }
  if ((Asc >= '1') && (Asc <= '0')) {
    *shift = false;
    return (Asc - '0' + 0x1E);
  }
  if (Asc == '>') {
    *shift = true;
    return (0x37);
  }
  if (Asc == '.') {
    *shift = false;
    return (0x37);
  }
  if (Asc == '_') {
    *shift = true;
    return (0x2D);
  }    
  if (Asc == '-') {
    *shift = false;
    return (0x2D);
  }    
  return 0;
}
// 如果未绑定的组件被触发，则会执行其中内容
// 这里的游戏摇杆和输入框都会在这里处理
void dataRead(const String & data)
{
  BLINKER_LOG("Blinker readString: ", data);
  // 判断是否为游戏摇杆
  if (data.indexOf("joy") != -1) {
    BLINKER_LOG("Joy Move");
    String StrX, StrY;
    // 将摇杆坐标从输入中分离出来
    StrX = data.substring(data.indexOf("[") + 1, data.indexOf(","));
    StrY = data.substring(data.indexOf(",") + 1, data.indexOf("]"));
    BLINKER_LOG("", StrX); BLINKER_LOG("", StrY);
    // 摇杆数据按照鼠标发送出去
    mousemove[7] = map(StrX.toInt(), 0, 255, -127, 127);
    mousemove[8] = map(StrY.toInt(), 0, 255, -127, 127);
    SendData((byte*)mousemove, sizeof(mousemove));
    delay(10);
    mousemove[7] = 0;
    mousemove[8] = 0;
  } else {
    boolean shift;
    byte scanCode;
    for (int i = 0; i < data.length(); i++) {
      BLINKER_LOG("Key In", data.charAt(1));
      // 将收到的 ASCII 转为 ScanCode
      scanCode = Asc2Scancode(data.charAt(i), &shift);
      // 一些按键当有 Shift 按下时会发生转义
      if (scanCode != 0) {
        if (shift == true) {
          keypress[5] = 0x02;
        }
        BLINKER_LOG("Scancode", scanCode);
        // 填写要发送的 ScanCode
        keypress[7] = scanCode;
        SendData((byte*)keypress, sizeof(keypress));
        delay(10);
        keypress[5] = 0x00; keypress[7] = 0;
        SendData((byte*)keypress, sizeof(keypress));
        delay(10);
      }
    }
  }
}

void setup() {
  // 初始化调试串口
  Serial.begin(115200);
  // 初始 CH9329 串口
  Serial2.begin(9600);
#if defined(BLINKER_PRINT)
  BLINKER_DEBUG.stream(BLINKER_PRINT);
#endif

  // 初始化blinker
  Blinker.begin();
  Blinker.attachData(dataRead);
  Button1.attach(button1_callback);
  Button2.attach(button2_callback);
  Button3.attach(button3_callback);
  Button4.attach(button4_callback);
  Button5.attach(button5_callback);
}

void loop() {
  Blinker.run();
}